Create a batch file for simple BeadChip accessioning to Illumina Microarray Analytics PGx Analysis
Last updated
Was this helpful?
Last updated
Was this helpful?
BeadChip DMAP files must be accessioned to Illumina Connected Analytics (ICA) prior to sending data to ICA during scanning on the iScan. The data from the scanner is automatically sent to ICA for cloud-based analysis of array data using the Illumina Microarray Analytics PGx Analysis software. The accessioning can be done manually using the ICA command-line tool and following the “Accession BeadChips” instructions on the Illumina website, . Alternatively, users can simplify the process by creating a batch (.bat) file. A batch file is a script file that contains a series of commands to be executed by a command-line interpreter application, eg, Command Prompt, in the Microsoft Windows operating system. Using a batch file saves time by automating tasks and allows for “push-button” accessioning of BeadChips for subsequent scans.
Whether created manually or using the .bat file, the command parses the DMAPs and moves them to one of two locations set by the user. The command requires three file paths:
The folder containing locally saved DMAP files.
The folder where successfully accessioned DMAP files are moved, eg, “Successfully Accessioned BeadChips.”
The folder where unsuccessfully accessioned DMAP files are moved, eg, “Unsuccessfully Accessioned BeadChips.”
The folders for the parsed DMAP files must be created before running the command.
The instructions below detail how to create a batch file. The template used contains all the required commands; users need to add only the specific file paths and credentials to create a functioning .bat file. These steps assume access to ICA and that the Command Line Interface (CLI) executable file has been downloaded from the ICA support site.
Support Resources
Procedure
Open a text editor, eg, Notepad, and create a new text file in a convenient location1.
Name the newly created text file AccessionBeadChips.txt.
Paste the text below into the text file and update the configuration accordingly between “Configuration Start” and “Configuration End.”
The domain, workgroup name (workgroupName), server url (serverUrl)2, and BeadChip directory (beadChipDirectory)3 (where the DMAPs are located) must be configured. ICA CLI path (icaCliPath) and single sign-on option (singleSignOn) may need to be updated based on the customer setup (see inline comments within the batch file).
Save the text file and exit the text editor.
Rename the text file from AccessionBeadChips.txt to AccessionBeadChips.bat.
Run the .bat file, enter username and password, and make sure that the command executes successfully using BeadChips. When run successfully:
BeadChips are moved from the “BeadChip” directory to the “Success” directory under the “BeadChip” directory.
The output will be successfully logged in the “create_beadchips” log file that is created under the “BeadChip” directory.
1 This file can be created in a folder that also contains the DMAP files, the Successfully Accessioned BeadChips folder, the Unsuccessfully Accessioned BeadChips folder, and the ICA CLI executable.
3 If the location of the DMAP files is a network directory, the Universal Naming Convention (UNC) file path in the form \server\share\folderContainingDMAPS is preferred.
The following is the text to paste into .txt file:
::===============================================================
:: Accession BeadChips into Illumina Connected Analytics (ICA)
::===============================================================
rem ==================== Configuration Start ====================
set domain=YOUR_DOMAIN
set workgroupName=YOUR_WORKGROUP_NAME
set serverUrl=YOUR_REGION.platform.illumina.com
set beadChipDirectory=YOUR_BEADCHIP_DIRECTORY
@rem If ICA CLI is installed in a different location than this file,
@rem update this value
set icaCliPath=ica.exe
@rem If single sign on is enabled for your domain, set this to true
set singleSignOn=false
rem ====================== Configuration End =====================
rem Default ICA and accessioning values
set icaConfigDir=%userprofile%.ica
set accessionSuccessFolder=%beadChipDirectory%\Successfully Accessioned BeadChips
set accessionFailureFolder=%beadChipDirectory%\Unsuccessfully Accessioned BeadChips
set accessionLogFile=%beadChipDirectory%\create_beadchips_log.txt
@echo off
echo Log into ICA with username and password
rem Create/Update configuration file
call :createDirectory "%icaConfigDir%" "ica configuration folder"
(
echo domain: %domain%
echo server-url: %serverUrl%
) > "%icaConfigDir%\config.yaml"
rem Add single sign on flag if needed
if %singleSignOn% == true (set ssoFlag=--sso) else (set ssoFlag=)
@echo on
set /P username=Enter username (eg, user@domain.com):
"%icaCliPath%" login "%username%" --workgroup-name "%workgroupName%" %ssoFlag%
@echo off
echo.
echo If username and password incorrect close this window and retry otherwise...
pause
echo Accessioning BeadChips...
rem Create success and failure directories if required
call :createDirectory "%accessionSuccessFolder%" accessionSuccessFolder
call :createDirectory "%accessionFailureFolder%" accessionFailureFolder
@echo on
"%icaCliPath%" infinium beadchips create "%beadChipDirectory%" "%accessionSuccessFolder%" "%accessionFailureFolder%" --log-file "%accessionLogFile%"
@echo off
echo.
echo BeadChip accessioning completed. Examine the above output and accessioning logs for more details: %accessionLogFile%
pause
rem Function to create directory if it does not exist
:createDirectory
if not exist "%~1" (
echo Creating %~2 folder, %~1
mkdir "%~1"
)
goto:eof
2 Refer to the list of Support Regions in the Illumina Knowledge article .
For additional information or questions, contact .
For any feedback or questions regarding this article (Illumina Knowledge Article #5887), contact Illumina Technical Support .